home *** CD-ROM | disk | FTP | other *** search
/ 8bitfiles.net/archives / archives.tar / archives / commodore-users-of-norman / CUON_13_(11-1984).d64 / recover scratch (.txt) < prev    next >
Commodore BASIC  |  2019-04-13  |  2KB  |  115 lines
  1. 100 REM   INITIALIZATION
  2. 101 :
  3. 102 CLR:DIM D$(255), E$(31)
  4. 103 POKE53280,15:POKE53281,12
  5. 104 PRINTCHR$(5)
  6. 105 NL$=CHR$(0):DT=18:DB=1
  7. 106 :
  8. 107 REM   HOUSEKEEPING
  9. 108 :
  10. 109 PRINT"[147]COMPLETE NAME OF"
  11. 110 INPUT"DELETED PROGRAM";P$
  12. 111 PRINT"[147]"
  13. 112 :
  14. 113 REM   OPEN FILES
  15. 114 :
  16. 115 OPEN15,8,15,"I0":GOSUB160
  17. 116 OPEN5,8,5,"#1":GOSUB160
  18. 117 OPEN6,8,6,"#2":GOSUB160
  19. 118 GOSUB150
  20. 119 :
  21. 120 REM   LOOP Z - EACH DIRECTORY ENTRY
  22. 121 REM   LOOP Y - STORE IN ARRAY E$
  23. 122 :
  24. 123 FORZ=0TO7:N$=""
  25. 124 FORY=0TO31
  26. 125 E$(Y)=D$(Z*32+Y):NEXT
  27. 126 :
  28. 127 REM   TEST PGM NAME
  29. 128 :
  30. 129 FORX=5TO20:N$=N$+E$(X):NEXT
  31. 130 IFP$=MID$(N$,1,LEN(P$))THEN138
  32. 131 NEXT
  33. 132 IFDB<>255THEN118
  34. 133 PRINT:PRINTP$;" NOT FOUND"
  35. 134 CLOSE5:CLOSE6:CLOSE15:END
  36. 135 :
  37. 136 REM   CHANGE TYPE & WRITE BUFFER
  38. 137 :
  39. 138 F$=CHR$(130)
  40. 139 D$(Z*32+2)=F$:PRINT
  41. 140 PRINTSPC(10);"WRITING ";TK;SC:PRINT
  42. 141 PRINT#15,"B-P";6;0:GOSUB160
  43. 142 FORW=0TO255:W$=D$(W)
  44. 143 PRINT#6,W$;:PRINTASC(W$);:NEXT
  45. 144 PRINT"[160]":PRINT
  46. 145 PRINT#15,"U2:";6;0;TK;SC
  47. 146 GOSUB160:GOTO165
  48. 147 :
  49. 148 REM   READ TRACK AND SECTOR
  50. 149 :
  51. 150 PRINT#15,"U1:";5;0;DT;DB:GOSUB160
  52. 151 PRINTSPC(10);"READING ";DT;DB:PRINT
  53. 152 FORX=0TO255
  54. 153 GET#5,W$:IFW$=""THENW$=NL$
  55. 154 D$(X)=W$:PRINTASC(W$);:NEXT
  56. 155 TK=DT:SC=DB:PRINT:PRINT
  57. 156 DT=ASC(D$(0)):DB=ASC(D$(1)):RETURN
  58. 157 :
  59. 158 REM   CHECK DISK STATUS
  60. 159 :
  61. 160 INPUT#15,EN,EM$,ET,ES
  62. 161 PRINT,"STATUS ";EN;EM$;ET;ES:PRINT
  63. 162 RETURN
  64. 163 REM   ALL DONE
  65. 164 :
  66. 165 CLOSE5:CLOSE6:CLOSE15
  67. 166 IFEN<>0THEN168
  68. 167 PRINT,"RECOVERY DONE"
  69. 168 END
  70. 169 :
  71. 170 REM  TITLE:   RECOVER (PROGRAM)
  72. 171 REM  AUTHOR:  B. SNEED
  73. 172 REM  DATE:    04/15/83
  74. 173 :
  75. 174 REM  THIS PROGRAM CAN BE USED TO
  76. 175 REM  RECOVER ANY PROGRAM ON A DISK
  77. 176 REM  THAT STILL HAS A ENTRY IN THE
  78. 177 REM  DIRECTORY AND THE ACTUAL DATA
  79. 178 REM  HAS NOT BEEN WRITTEN OVER.
  80. 179 :
  81. 180 REM  METHODOLOGY:
  82. 181 REM
  83. 182 REM  1.  EXECUTE PROGRAM DIRLIST TO
  84. 183 REM      VERIFY THAT THERE IS STILL
  85. 184 REM      A DIRECTORY ENTRY.
  86. 185 :
  87. 186 REM  2.  THE ENTRY TYPE SHOULD BE
  88. 187 REM      "D" INDICATING DELETED.
  89. 188 :
  90. 189 REM  3.  EXECUTE THIS PROGRAM AND
  91. 190 REM      ANSWER THE PROMPT WITH THE
  92. 191 REM      FULL COMPLETE NAME, DO NOT
  93. 192 REM      USE THE * WILDCARD.
  94. 193 :
  95. 194 REM  4.  IF THERE IS AN ERROR, THIS
  96. 195 REM      WILL TERMINATE AND NO HARM
  97. 196 REM      IS DONE.
  98. 197 :
  99. 198 REM  5.  IF THE RECOVERY SUCCESSFUL
  100. 199 REM      MESSAGE APPEARS, IT MEANS
  101. 200 REM      THE DIRECTORY AND ONLY IT
  102. 201 REM      HAS BEEN MODIFIED.
  103. 202 :
  104. 203 REM  6.  LOAD AND LIST THE PROGRAM
  105. 204 REM      VERIFING EVERYTHING IS OK.
  106. 205 :
  107. 206 REM  7.  IF IT IS - WELL GREAT!
  108. 207 :
  109. 208 REM  8   IF IT ISN'T - TOO BAD.
  110. 209 :
  111. 210 REM  TO SPEED UP EXECUTION AND LOAD
  112. 211 REM  TIME, YOU CAN USE VIC-TREE TO
  113. 212 REM  DELETE ALL REMARKS LINES WITH
  114. 213 REM  A SINGLE : ONLY.
  115.